Suika 2 コマンドリファレンス

@bg

背景を変更します。背景の変更後、キャラクタはステージ上からいなくなります。

@bg sample.png 1.5
@bg sample.png
@bg sample.png 1.5 c
@bg #ff8080 1.5 curtain-left

@bgm

BGMを再生します。BGMファイルはフォルダbgmに格納されている必要があります。再生可能なファイル形式は、44.1kHzのOgg Vorbisのみです。

@bgm sample.ogg
@bgm stop
@vol bgm 0 2
@wait 2
@bgm stop

@ch

キャラクタを変更します。キャラクタの位置は、上位レイヤから順に、中央前面(center)、右(right)、左(left)、中央背面(back)の4つがあります。

@ch center sample.png 0.5
@ch c sample.png 0.5
@ch c none 0.5
@ch c sample.png
@ch c sample.png 1.0 mask
@ch c sample.png 1.0 normal
@ch c sample.png 1.0 n 100 50
@ch c sample.png 1.0 n 0 0 show

@cha

キャラクタのアニメーションを行います。キャラクタの位置の指定とアルファ値の指定は@chコマンドを参照してください。

@cha center 1.0 move -600 0 hide
@cha center 1.0 accel -600 0 hide
@cha center 1.0 brake -600 0 hide
@ch right sample.png 0 n 600 0 hide
@cha right 2.0 move -600 0 show

@click

クリックされるのを待ちます。待っている間、メッセージボックスは非表示となります。

@click

@gosub

サブルーチンにジャンプします。@returnで戻ります。

@gosub SUB

:SUB
ここに何らかの処理やメッセージを記述します。
@return

@goto

ラベルにジャンプします。ループを作成するときや、ループから抜け出す際に使用します。

:abc
ここに何らかの処理やメッセージを記述します。
@goto abc
@goto $LOAD

@if

条件式が成立するときラベルにジャンプします。
利用できる演算子は>,>=,==,<=,<,!=です。

@if $1 >= 10 abc
変数$1が10未満のときの処理を記述します。
:abc

ラベル

ジャンプ先となるラベルを作成します。

:ジャンプ先
何かメッセージを表示する
@goto ジャンプ先

@load

スクリプトファイルにジャンプします。スクリプトファイルはフォルダtxtの中に存在する必要があります。

@load 001.txt

@menu

画像を2枚使ってメニューを表示します。ボタンを16個まで作成できます。基本的に1枚目の画像が表示されますが、ボタンがマウスでポイントされている間は、そのボタンの領域だけ2枚目の画像が表示されます。メニュー画面は右クリックでキャンセルできません。

@menu menu.png menu-selected.png START 640 480 240 120
:START

メッセージ

メッセージボックスにテキストを出力します。
で改行できます。$数字で変数の値を出力できます。

こんにちは、世界。

@news

@switchの亜種です。親選択肢の最初の4つが、北、東、西、南に表示されます。

親選択肢に限り、表示メッセージに*を指定することで、非表示にすることができます。

@retrospect

CG鑑賞モードを実行します。@menuと同様に2枚の画像を使用します。@menuとの違いは、作成できるボタンの数が12個までであることと、それぞれのボタンに変数を指定して、変数の値が0のときはボタンを隠すことです。また、@menuと異なり右クリックでキャンセルが可能です。

引数が多いです。先頭から順に、背景画像、選択時に上書きされる画像、変数の値が0のときに背景を塗りつぶす色のR、G、B、各ボタンの幅、各ボタンの高さと続きます。以降、ボタンの数だけ、ジャンプ先ラベル、チェックする変数、ボタンのX座標、ボタンのY座標、の4つが続きます。

@retrospect menu.png menu-selected.png 0 0 0 320 240 PICTURE1 $1 320 240
キャンセルされました
@goto END
:PICTURE1
@bg picture1.png 1.0
@click
:END

@return

サブルーチンから戻ります。

@gosub SUB

:SUB
ここに何らかの処理やメッセージを記述します。
@return

@se

SEを再生します。SEファイルはフォルダseに格納されている必要があります。再生可能なファイル形式は、44.1kHzのOgg Vorbisのみです。

@se click.ogg
@se click.ogg voice

@select

選択肢を表示してラベルにジャンプします。選択肢の数は3つに固定されています。

@select label1 label2 label3 おはよう こんにちは こんばんは
:label1
おはよう
@goto end
:label2
こんにちは
@goto end
:label3
こんばんは
:end

セリフ

メッセージボックスにセリフを出力します。また、名前ボックスに名前を出力します。ボイスを再生することができます。ボイスファイルは、フォルダcvの中に存在する必要があります。ボイスファイルの形式は、44.1kHzのOgg Vorbisである必要があります。メッセージと同様に、
で改行できます。$数字で変数の値を出力できます。

*名前*こんにちは、世界。
*名前*001.ogg*こんにちは、世界。
*名前*@beep.ogg*こんにちは、世界。

@set

変数に値をセットします。セーブデータごとに値が異なるローカル変数は、$0から$9999までの10000個を利用できます。変数の初期値は0です。すべてのセーブデータで共通の値となるグローバル変数は、$10000から$10999までの1000個を利用できます。利用できる演算子は、=, +=, -=, *=, /=, %=です。

@set $0 = 1
@set $10 += 23
@set $0 = $RAND
@set $1 += $2

@setsave

メッセージおよび選択肢の待ち時間に右クリックで表示されるセーブ・ロード画面の呼び出しを、有効化もしくは無効化します。

@setsave enable
@setsave disable

@shake

画面を揺らします。

@shake horizontal 1.0 3 100
@shake vertical 1.0 3 100

@switch

最大2階層のコマンド選択肢を表示します。親コマンドと子コマンドがそれぞれ8個ずつで、合計で最大64分岐を記述できます。1階層のメニューとして利用することも可能です。

@switch 親選択肢1 親選択肢2 * * * * * * LABEL1 * * * * * * * * * * * * * * * LABEL2 * * * * * * * * * * * * * * *
@switch 親選択肢1 親選択肢2 * * * * * * LABEL1 子選択肢1 LABEL2 子選択肢2 * * * * * * * * * * * * LABEL3 子選択肢3 LABEL4 子選択肢4 * * * * * * * * * * * *

@vol

時間を指定してボリュームを調整します。調整できる出力は、小文字でbgmvoiceseの3つのストリームです。3つのストリームの音量はセーブデータごとに別な値を取るため、演出目的で頻繁に変更することが可能です。

全てのセーブデータで共通となるグローバルなマスター音量を設定するには、大文字でBGMVOICESEを指定します。マスター音量を指定する際、時間には0を指定してください。

@vol bgm 0.5 1.0
@vol b 0.5 1.0
@vol BGM 0.5 0

@wait

時間を指定して待機します。途中、キーボードやマウスの入力があれば待機を終了します。待機中、メッセージボックスは表示されません。

@wait 5.0